Windows 10 Gratis – Sistema Definitivo

@echo off
title Reparar Icono Desaparecido para Reserva de Windows 10 por Kobra17
goto foreward
:foreward
color 0b
cls
echo Los procedimientos dentro de este ejecutable pueden modificar archivos y la configuración del Registro.
echo No se asume ninguna responsabilidad por el uso de este archivo ejecutable.
echo Este Ejecutable se proporciona sin ningun tipo de garantía. Cualquier daño causado es bajo su propia responsabilidad.
echo.
echo Los archivos .bat son casi siempre marcados por el anti-virus, NO DUDE EN REVISAR el código si no está seguro.
echo.
echo Si entiendes todo lo anterior y ACEPTAS - pulsa cualquier tecla para continuar...
pause > NUL
goto elevatecheck
:elevatecheck
color 0c
cls
echo Comprobando permisos de Administrador...
echo.
echo.
openfiles > NUL 2>&1
if %errorlevel%==0 (
echo ¡Encontrados permisos! Procediendo...
goto vercheck
) else (
echo No lo estas ejecutando como administrador...
echo ¡Este ejecutable no puede hacer su trabajo sin permisos de Administrador!
echo.
echo Haga clic derecho y seleccione "Ejecutar como administrador" e inténtelo de nuevo...
echo.
echo Presiona cualquier tecla para salir...
pause > NUL
exit
)
:vercheck
color 0c
cls
echo Realizando comprobaciones previas...
for /f "tokens=4-5 delims=. " %%i in ('ver') do set version=%%i.%%j
if "%version%"=="6.3" set allow=1
if "%version%"=="6.1" set allow=1
if %allow%==1 goto warning
set allow=0
echo.
echo No pasas los pre-requisitos.
echo Si estás ejecutando Windows 8, vete a instalar Windows 8.1 en la tienda.
echo.
echo Presiona cualquier tecla para salir...
pause > NUL
exit
:warning
color 0b
cls
echo Advertencia sobre las licencias...
echo.
echo.
echo El hecho de que la versión sea correcta, ¡no significa que reunas los requisitos para la actualización gratuita!
echo En particular, las siguientes NO pueden optar a Windows 10 a través de Windows Update...
echo.
echo Windows 7 RTM
echo Windows 8
echo Windows 8.1 RTM
echo Windows RT
echo Windows Phone 8.0
echo.
echo Presiona cualquier tecla para salir...
pause > NUL
goto menu
:menu
color 0b
cls
echo Menú Principal
echo.
echo.
echo 1^) Verificar Estado de Actualización
echo 2^) Método Rápido #1 ^[de JC desde answers.microsoft.com^]
echo 3^) Método Rápido #2 ^[de KevinStevens_845 desde answers.microsoft.com^]
echo 4^) Método Largo #1 ^[de Yaqub K desde answers.microsoft.com^]
echo 5^) SALIR
echo.
set /p mmchoice=Selection:
if %mmchoice%==1 goto upstatus
if %mmchoice%==2 goto qm1
if %mmchoice%==3 goto qm2
if %mmchoice%==4 goto lm1
if %mmchoice%==5 exit
goto error
:error
color 0C
cls
echo Menú principal - ¡Error!
echo.
echo.
echo No has introducido una entrada válida.
echo.
echo Pulsa cualquier tecla para volver al menú principal y prueba de nuevo.
pause > NUL
goto menu
:upstatus
cls
echo Comprobar el estado de instalación de la actualización apropiada...
echo.
echo.
if "%version%"=="6.3" goto upstatus8
if "%version%"=="6.1" goto upstatus7
goto menu
:upstatus8
echo Windows 8^+ detectado...
echo.
set upcheck=3035583
echo Comprobando actualización KB%upcheck%...
dism /online /get-packages | findstr %upcheck% > NUL
if %errorlevel%==0 (
echo ¡La actualización KB%upcheck% está instalada!
set missupdate=0
) else (
echo ¡La actualización KB%upcheck% No se encuentra!
set missupdate=1
)
echo.
set upcheck=3035583
echo Comprobando actualización KB%upcheck%...
dism /online /get-packages | findstr %upcheck% > NUL
if %errorlevel%==0 (
echo ¡La actualización KB%upcheck% está instalada!
) else (
echo ¡No se encuentra la actualización KB%upcheck%!
set /a missupdate=%missupdate%+1>NUL
)
echo.
echo.
if %missupdate%==0 (
echo No se echa en falta ninguna actualización, ¡enhorabuena!
) else (
echo Faltan %missupdate% actualizacion^(s^).
)
echo Pulsa cualquier tecla para volver al menú principal...
pause > NUL
goto menu
:upstatus7
echo Windows 7 detectado...
echo.
set upcheck=3035583
echo Comprobando actualización KB%upcheck%...
dism /online /get-packages | findstr %upcheck% > NUL
if %errorlevel%==0 (
echo ¡La actualización KB%upcheck% está instalada!
set missupdate=0
) else (
echo ¡No se encuentra la actualización KB%upcheck%!
set missupdate=1
)
echo.
set upcheck=2952664
echo Comprobando actualización KB%upcheck%...
dism /online /get-packages | findstr %upcheck% > NUL
if %errorlevel%==0 (
echo ¡La actualización KB%upcheck% está instalada!
) else (
echo ¡No se encuentra la actualización KB%upcheck%!
set /a missupdate=%missupdate%+1>NUL
)
echo.
echo.
if %missupdate%==0 (
echo No se echa en falta ninguna actualización, ¡enhorabuena!
) else (
echo Faltan %missupdate% actualizacion^(s^).
)
echo Pulsa cualquier tecla para volver al menú principal...
pause > NUL
goto menu
:qm1
cls
echo Método Rápido #1 ^[JC desde answers.microsoft.com^]
echo.
echo.
echo Actualizando Registro...
reg add "HKLM\Software\Microsoft\Windows NT\CurrentVersion\AppCompatFlags\UpgradeExperienceIndicators" /v UpgEx /t REG_SZ /d Green /f
echo Tratando de lanzar la aplicación a la barra de tareas...
%SystemRoot%\System32\GWX\GWX.exe /taskLaunch
echo.
echo Este método se ha completado - ¡y además es instantáneo!
echo Debes ver el icono de Windows 10 en el área de notificación.
echo Si no es asi, vuelve al menú e inténtalo con otro método.
echo.
echo Pulsa cualquier tecla para volver al menú principal...
pause > NUL
goto menu
:qm2
echo Método Rápido #2 ^[KevinStevens_845 desde answers.microsoft.com^]
echo.
echo.
echo Tratando de lanzar la tarea GWX...
%SystemRoot%\System32\GWX\GWX.exe /taskLaunch
echo Tratando de refrescar la configuración de GWX...
%SystemRoot%\System32\GWX\GWXConfigManager.exe /RefreshConfig
echo.
echo Este método se ha completado - pero podría tardar unos minutos.
echo En aproximadamente 10 minutos se debe ver el icono de Windows 10 en área de notificación.
echo Si no es asi, vuelve al menú e inténtalo con otro método.
echo.
echo Pulsa cualquier tecla para volver al menú principal...
pause > NUL
goto menu
:lm1
cls
echo Método Largo #1 ^[Yaqub K desde answers.microsoft.com^]
echo.
echo.
echo Este método puede tardar desde 10 minutos en adelante.
echo Se ha tenido ejecutando hasta 40 minutos durante las pruebas...
echo.
echo Este bucle tardara un tiempo, pero por favor, debes tener en cuenta...
echo Si ves en el "ESTADO" otra cosa que "RUNNING", algo va mal.
echo Si eso sucede, cierra el archivo por lotes y empieza de nuevo. Puede pasar un par de veces.
echo.
echo Además, debido a la forma en que fue escrito este script, puede que tengas que volver a ejecutarlo de nuevo para continuar.
echo.
echo Si entiendes lo anterior, pulsa cualquier tecla para continuar.
pause > NUL
color 0c
cls
echo El trabajo ha comenzado...
REG QUERY "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\AppCompatFlags\UpgradeExperienceIndicators" /v UpgEx | findstr UpgEx
if "%errorlevel%"=="0" goto RunGWX
reg add "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\AppCompatFlags\Appraiser" /v UtcOnetimeSend /t REG_DWORD /d 1 /f
schtasks /run /TN "\Microsoft\Windows\Application Experience\Microsoft Compatibility Appraiser"
echo ¡¡¡ESTO PUEDE CAUSAR UN BUCLE - VERIFICAR QUE EL ESTADO ES RUNNING!!! &echo ¡¡¡ESTO PUEDE CAUSAR UN BUCLE - VERIFICAR QUE EL ESTADO ES RUNNING!!! &echo ¡¡¡ESTO PUEDE CAUSAR UN BUCLE - VERIFICAR QUE EL ESTADO ES RUNNING!!!
:CompatCheckRunning
schtasks /query /TN "\Microsoft\Windows\Application Experience\Microsoft Compatibility Appraiser"
schtasks /query /TN "\Microsoft\Windows\Application Experience\Microsoft Compatibility Appraiser" | findstr Ready
if not "%errorlevel%"=="0" ping localhost > NUL &goto :CompatCheckRunning
:RunGWX
schtasks /run /TN "\Microsoft\Windows\Setup\gwx\refreshgwxconfig"
color 0b
cls
echo.
echo Este método se ha completado.
echo Los informes indican que podría tardar hasta una hora en poder verse el icono.
echo También se recomienda reiniciar el PC si no ha aparecido después de esa hora de espera.
echo.
echo Si no ves el icono en el área de notificación, prueba con otro método.
echo Si utilizas este método como último, por favor visita los Foros de Microsoft Answers para encontrar otra soluciones.
echo.
echo Pulsa cualquier tecla para volver al menú principal...
pause > NUL
goto menu